Getting Groups (Models)

Groups are a collection of display, interaction, and mannequin entities. Groups can be dynamically moved, spawned, and used in various ways.

Spawn Groups/Models

#Get a savedgroup from storage
set {_savedgroup} to saved group tagged "mygroup" from local storage

#Spawn the group
deu spawn {_savedgroup} at {_location}

##Spawn the group and store
deu spawn {_savedgroup} at {_location} and store the result in {_activegroup}

#Spawn the group with options
deu spawn {_savedgroup} at {_location} and store the result in {_activegroup}:
    packet: false #Whether the group should spawn using packets
    teleport-duration: 2
    billboard: VERTICAL
    persistent: true
    visible: true
    brightness: 10 and 5 #Block and Sky, -1 and -1 to reset
    spawnanimation: true #Play the group's spawn animation, if set

Get Existing Non-Packet-Based groups from entities or parts

#Get/Create an active group from a display entity
set {_activegroup} to {_displayentity}'s active group

#Get the active group from an existing active part
set {_activegroup} to {_activepart}'s active group

#Get the active group of a part filter
set {_activegroup} to {_partfilter}'s active group

Get Existing Non-Packet-Based Groups already in the world

#Get the group closest to a location, within a range
set {_nearestGroup} to nearest spawnedgroup within 4 blocks of {_location}

#Get all groups around a location
set {_nearestGroups::*} to all spawnedgroups within 6 blocks of {_location}

# Get the selected group of a player
set {_selectedGroup} to player's selected group

Getting Persistent Packet-Based Groups already in the world

Persistent packet-based display entity groups have an ID that stays the same across game sessions. That ID can be used to get the group again in the future

#Get the ID of a persistent packet-based group for use in future sessions
set {id} to {_packetgroup}'s persistent id

#Get the persistent packet-based group by its id 
set {_mypersistentgroup} to persistent packet group with id {id}

Despawning/Unregistering Groups

Groups should be unregistered after their purpose has been fulfilled. Unregistering groups prevents future usage.

#Unregister an active group
unregister {_activegroup}

#Unregister an active group, and despawn. This is not required for packet-based groups
unregister {_activegroup} and despawn

#Unregister an active group, and despawn with forced chunk loading. This is not required for packet-based groups
unregister {_activegroup} and despawn with forced chunk loading